Dicas sobre o componente DBGrid do Delphi

Dicas sobre o componente DBGrid do Delphi

  outubro 31, 2013    Anônimo

---

O TDBGrid talvez seja um dos componentes mais utilizados no dia a dia de um desenvolvedor Delphi.

Resolvi juntar algumas dicas simples e práticas para melhorar a utilização deste componente. Para melhor demonstrar os resultados dos exemplos, criei um projeto teste com dados fictícios em um ClienteDataSet, porem, os exemplos que fiz são quase que 100% independentes do tipo de DataSet utilizado.

Fazer linha zebrada :Temos que verificar se o numero do registro atual do DataSet é impar ou par, nos dataSet temos a propriedade RecNo que consiste no numero do registro ativo no dataSet e para saber se esse numero é impar ou par, basta usar o método Odd que retornar true se um numero é impar e false se esse for par. Para implementar essa rotina, iremos utilizar o evento OnDrawColumnCell do TDbGrid que consiste no evento em que os dados são “desenhados” no grid.

procedure TForm1.dbGridTesteDrawColumnCell(Sender: TObject; const Rect: TRect;
  DataCol: Integer; Column: TColumn; State: TGridDrawState);
begin
  if Odd(ClientDataSet1.RecNo) then
    dbGridTeste.Canvas.Brush.Color := clWindow
  else
    dbGridTeste.Canvas.Brush.Color := clMoneyGreen;
  dbGridTeste.Canvas.FillRect(Rect);
  dbGridTeste.DefaultDrawColumnCell(Rect, DataCol, Column, State);
end;

Utilizamos a propriedade Canvas, dentro de canvas a propriedade Brush, que é utilizada para pintar o fundo de uma linha no grid. O resultado deste exemplo ficaria desta forma.

Destacar linhas: Nesse exemplo vamos destacar as linhas com da fonte vermelha e em negrito nos que tiverem o salario menor de 1900,00.

procedure TFSistema.dbGridTesteDrawColumnCell(Sender: TObject; const Rect: TRect;
  DataCol: Integer; Column: TColumn; State: TGridDrawState);
begin
  if ClientDataSet.FieldByName('VALOR').AsFloat <= 1900 then  begin
    if (gdSelected in State) then
      dbGridTeste.Canvas.Brush.Color := clRed
    else begin
      dbGridTeste.Canvas.Font.Style := [fsBold];
      dbGridTeste.Canvas.Font.Color := clRed;
    end;
    dbGridTeste.Canvas.FillRect(Rect);
    dbGridTeste.DefaultDrawColumnCell(Rect,DataCol,Column,State);
  end;
end;

Agora estamos utilizando "gdSelected in State", se resultar true significa que esta posicionado na linha do TDBGrid.

Destacar uma célula e uma coluna: Agora vamos fazer por célula, quando o valor for menor que 1900,00 a célula vai ficar vermelha e a letra branca e se maior a célula ficara verde. Algo semelhante ao exemplo anterior

procedure TFSistema.dbGridTesteDrawColumnCell(Sender: TObject; const Rect: TRect;
  DataCol: Integer; Column: TColumn; State: TGridDrawState);
begin
  if Column.FieldName = 'VALOR' then begin
    if Column.Field.AsFloat <= 1900 then begin
      dbGridTeste.Canvas.Brush.Color := clRed;
      dbGridTeste.Canvas.Font.Color := clWhite;
    end else
      dbGridTeste.Canvas.Brush.Color := clTeal;
    dbGridTeste.Canvas.FillRect(Rect);
    dbGridTeste.DefaultDrawColumnCell(Rect,DataCol,Column,State);
  end;
end;

Inserir um checkbox em um coluna:Já fiz um post com apenas esse exemplo, e um dos que mais utilizo. Vamos inserir o checkBox com isso vamos usar um campo integer o SEL e nele vamos jogar 1 ou 0 em caso de 0 esta desmarcado e 1 marcado, conseguimos fazer isto através da variável Check.

procedure TFSistema.dbGridTesteDrawColumnCell(Sender: TObject; const Rect: TRect;
  DataCol: Integer; Column: TColumn; State: TGridDrawState);
 var
  R: TRect;
  Check: integer;
begin
  if (Column.Index = 0) then begin
    if (ClientDataSet.FieldByName('SEL').Value = 0) then
      Check := DFCS_BUTTONCHECK or DFCS_CHECKED
    else
      Check := DFCS_BUTTONCHECK;
    dbGridTeste.Canvas.FillRect(Rect);
    R := Rect;
    InflateRect(R, -2, -2);
    DrawFrameControl(dbGridTeste.Canvas.Handle, R, DFC_BUTTON, Check);
  end;
end;

 

Para deixar um pouco mais prático o uso do checkBox no DBgrid, podemos fazer uma rotina para marcar ou desmarcar o componente quando a célula que ele está seja clicada

procedure TFSistema.dbGridTesteDblClick(Sender: TObject);
begin
  ClientDataSet.Edit;
  ClientDataSetSEL.Value := IfThen(ClientDataSetSEL.Value = 1, 0, 1);
  ClientDataSet.Post;
end;

Inserir uma imagem em uma coluna:Vamos utilizar o componente TImageList para poder armazenar as imagens. Com a mesma ideia do marcar e desmarcar do CheckBox.

Já no TDBGrid vai o código abaixo: 

procedure TFSistema.dbGridTesteDrawColumnCell(Sender: TObject; const Rect: TRect;
  DataCol: Integer; Column: TColumn; State: TGridDrawState);
var
  lIcon: TBitmap;
begin
  if (Column.Index = 0) then begin
    lIcon := TBitmap.Create;
    lIcon.Transparent := True;
    ImageList1.GetBitmap(ifthen(ClientDataSetSEL.Value = 1, 1, 0), lIcon);
    try
      dbGridTeste.Canvas.FillRect(Rect);
      dbGridTeste.Canvas.Draw(Round((Rect.Left + Rect.Right - lIcon.Width) / 2), Rect.Top, lIcon);
    finally
      FreeAndNIl(lIcon);
    end;
  end;
end;

Utilizar um ComboBox em uma coluna: Dentro dasColumns do Dbgrid existe a propriedade PickList que tem o objeto do tipo TStrings e é utilizado exatamente para dar esse efeito do combo dentro de uma célula do grid. Então para demonstrar a utilização desta propriedade, dentro do método de carregar os dados, vamos colocar o seguinte trecho de código:

procedure TFSistema.DoCreate;
begin
  with dbGridTeste.Columns[2].PickList do begin
    Clear;
    Add('GERENTE');
    Add('REPRESENTANTE');
    Add('ENCANADOR');
    Add('VENDEDOR');
  end;
end; 

Ordenar dinamicamente pela coluna clicada pelo usuário: Vamos fazer uma ordenação que o usuário escolha por qual campo ele quer fazer a ordenação, clicando no titulo de uma coluna no DBgrid. Utilizaremos o IndexFieldNamesque .

Exemplo: Download do exemplo